Dpkg::Dist::Files: New perl module

scripts/Dpkg/Dist/Files.pm

@@ -0,0 +1,141 @@
+# Copyright © 2014 Guillem Jover <guillem@debian.org>
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, see <https://www.gnu.org/licenses/>.
+
+package Dpkg::Dist::Files;
+
+use strict;
+use warnings;
+
+our $VERSION = '0.01';
+
+use parent qw(Dpkg::Interface::Storable);
+
+use Dpkg::Gettext;
+use Dpkg::ErrorHandling;
+
+sub new {
+    my ($this, %opts) = @_;
+    my $class = ref($this) || $this;
+
+    my $self = {
+        options => [],
+        files => {},
+        order => [],
+    };
+    foreach my $opt (keys %opts) {
+        $self->{$opt} = $opts{$opt};
+    }
+    bless $self, $class;
+
+    return $self;
+}
+
+sub parse {
+    my ($self, $fh, $desc) = @_;
+    my $count = 0;
+
+    local $_;
+    binmode $fh;
+
+    while (<$fh>) {
+        chomp;
+
+        my %file;
+
+        if (m/^(([-+.0-9a-z]+)_([^_]+)_([-\w]+)\.([a-z0-9.]+)) (\S+) (\S+)$/) {
+            $file{filename} = $1;
+            $file{package} = $2;
+            $file{version} = $3;
+            $file{arch} = $4;
+            $file{package_type} = $5;
+            $file{section} = $6;
+            $file{priority} = $7;
+        } elsif (m/^([-+.,_0-9a-zA-Z]+) (\S+) (\S+)$/) {
+            $file{filename} = $1;
+            $file{section} = $2;
+            $file{priority} = $3;
+        } else {
+            error(_g('badly formed line in files list file, line %d'), $.);
+        }
+
+        if (defined $self->{files}->{$file{filename}}) {
+            warning(_g('duplicate files list entry for file %s (line %d)'),
+                    $file{filename}, $.);
+        } else {
+            $count++;
+            $self->{files}->{$file{filename}} = \%file;
+            push @{$self->{order}}, $file{filename};
+        }
+    }
+
+    return $count;
+}
+
+sub get_files {
+    my ($self) = @_;
+
+    return map { $self->{files}->{$_} } @{$self->{order}};
+}
+
+sub get_file {
+    my ($self, $filename) = @_;
+
+    return $self->{files}->{$filename};
+}
+
+sub add_file {
+    my ($self, $filename, $section, $priority) = @_;
+
+    # XXX: Ideally we'd need to parse the filename, to match the behaviour
+    # on parse(), and initialize the other attributes, although no code is
+    # in need of this for now, at least in dpkg-dev.
+
+    if (not defined $self->{files}->{$filename}) {
+        push @{$self->{order}}, $filename;
+    }
+
+    $self->{files}->{$filename} = {
+        filename => $filename,
+        section => $section,
+        priority => $priority,
+    };
+}
+
+sub del_file {
+    my ($self, $filename) = @_;
+
+    delete $self->{files}->{$filename};
+
+    @{$self->{order}} = grep { $_ ne $filename } @{$self->{order}};
+}
+
+sub output {
+    my ($self, $fh) = @_;
+    my $str = '';
+
+    binmode $fh if defined $fh;
+
+    foreach my $filename (@{$self->{order}}) {
+        my $file = $self->{files}->{$filename};
+        my $entry = "$filename $file->{section} $file->{priority}\n";
+
+        print { $fh } $entry if defined $fh;
+        $str .= $entry;
+    }
+
+    return $str;
+}
+
+1;

scripts/Makefile.am

@@ -78,6 +78,7 @@ nobase_dist_perllib_DATA = \
 	Dpkg/Control/Hash.pm \
 	Dpkg/Control/Types.pm \
 	Dpkg/Deps.pm \
+	Dpkg/Dist/Files.pm \
 	Dpkg/ErrorHandling.pm \
 	Dpkg/Exit.pm \
 	Dpkg/File.pm \
@@ -200,6 +201,7 @@ test_cases = \
 	t/Dpkg_Substvars.t \
 	t/Dpkg_IPC.t \
 	t/Dpkg_Compression.t \
+	t/Dpkg_Dist_Files.t \
 	t/merge_changelogs.t
 
 test_data = \
@@ -247,6 +249,7 @@ test_data = \
 	t/Dpkg_Control/bogus-armor-nested.dsc \
 	t/Dpkg_Control/bogus-armor-spaces.dsc \
 	t/Dpkg_Substvars/substvars1 \
+	t/Dpkg_Dist_Files/files-byhand \
 	t/merge_changelogs/ch-old \
 	t/merge_changelogs/ch-a \
 	t/merge_changelogs/ch-b \

scripts/po/POTFILES.in

@@ -39,6 +39,7 @@ scripts/Dpkg/Control/HashCore.pm
 scripts/Dpkg/Control/Hash.pm
 scripts/Dpkg/Control/Types.pm
 scripts/Dpkg/Deps.pm
+scripts/Dpkg/Dist/Files.pm
 scripts/Dpkg/ErrorHandling.pm
 scripts/Dpkg/Exit.pm
 scripts/Dpkg/Index.pm

scripts/t/Dpkg_Dist_Files.t

@@ -0,0 +1,95 @@
+#!/usr/bin/perl
+#
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, see <https://www.gnu.org/licenses/>.
+
+use strict;
+use warnings;
+
+use Test::More tests => 8;
+
+use_ok('Dpkg::Dist::Files');
+
+my $srcdir = $ENV{srcdir} // '.';
+my $datadir = $srcdir . '/t/Dpkg_Dist_Files';
+
+my $expected;
+my %expected = (
+    'pkg-templ_1.2.3_arch.type' => {
+        filename => 'pkg-templ_1.2.3_arch.type',
+        package => 'pkg-templ',
+        package_type => 'type',
+        version => '1.2.3',
+        arch => 'arch',
+        section => 'section',
+        priority => 'priority',
+    },
+    'pkg-arch_2.0.0_amd64.deb' => {
+        filename => 'pkg-arch_2.0.0_amd64.deb',
+        package => 'pkg-arch',
+        package_type => 'deb',
+        version => '2.0.0',
+        arch => 'amd64',
+        section => 'admin',
+        priority => 'required',
+    },
+    'pkg-indep_0.0.1-2_all.deb' => {
+        filename => 'pkg-indep_0.0.1-2_all.deb',
+        package => 'pkg-indep',
+        package_type => 'deb',
+        version => '0.0.1-2',
+        arch => 'all',
+        section => 'net',
+        priority => 'standard',
+    },
+    'other_0.txt' => {
+        filename => 'other_0.txt',
+        section => 'text',
+        priority => 'optional',
+    },
+    'BY-HAND-file' => {
+        filename => 'BY-HAND-file',
+        section => 'webdocs',
+        priority => 'optional',
+    },
+);
+
+my $dist = Dpkg::Dist::Files->new();
+$dist->load("$datadir/files-byhand") or error('cannot parse file');
+
+$expected = 'pkg-templ_1.2.3_arch.type section priority
+pkg-arch_2.0.0_amd64.deb admin required
+pkg-indep_0.0.1-2_all.deb net standard
+other_0.txt text optional
+BY-HAND-file webdocs optional
+';
+
+is($dist->output(), $expected, 'Parsed dist file');
+foreach my $f ($dist->get_files()) {
+    is_deeply($f, $expected{$f->{filename}},
+              "Detail for individual dist file $f->{filename}");
+}
+
+$expected = 'pkg-templ_1.2.3_arch.type section priority
+pkg-arch_2.0.0_amd64.deb void imperative
+other_0.txt text optional
+BY-HAND-file webdocs optional
+added-on-the-fly void wish
+';
+
+$dist->add_file('added-on-the-fly', 'void', 'wish');
+$dist->add_file('pkg-arch_2.0.0_amd64.deb', 'void', 'imperative');
+$dist->del_file('pkg-indep_0.0.1-2_all.deb');
+is($dist->output(), $expected, 'Modified dist object');
+
+1;

scripts/t/Dpkg_Dist_Files/files-byhand

@@ -0,0 +1,5 @@
+pkg-templ_1.2.3_arch.type section priority
+pkg-arch_2.0.0_amd64.deb admin required
+pkg-indep_0.0.1-2_all.deb net standard
+other_0.txt text optional
+BY-HAND-file webdocs optional